Excel에서 KB, MB, GB 등으로 셀의 바이트 서식을 어떻게 지정할 수 있습니까?

Excel에서 KB, MB, GB 등으로 셀의 바이트 서식을 어떻게 지정할 수 있습니까?

---

바이트 단위의 셀에 값이 있습니다. 그러나 아무도 728398112238을 읽을 수 없습니다. 차라리 678.37GB라고 말하고 싶습니다.

비교적 쉽게 서식을 지정하는 공식을 작성하려면 (여기 하나 : http://www.yonahruss.com/2007/02/format-excel-numbers-as-gb-mb-kb-b.html )

그러나 이것을 '형식'으로 수행하는 방법이 있습니까? 셀에 큰 숫자를 넣고 싶지만 사람이 읽을 수있는 형식으로 표시되도록합니다.

---

Excel의 서식 기능에서는 실제로 계산을 수행 할 수 없습니다. 다음과 같은 것을 사용하여 대략적인 추정을 할 수 있습니다.

[<500000]#,##0" B ";[<500000000]#,##0,," MB";#,##0,,," GB"

---

다음은 제가 사용해온 것입니다.-

[<1000000]0.00," KB";[<1000000000]0.00,," MB";0.00,,," GB"

잘 작동하는 것 같습니다.

---

Excel 형식 조건은 숫자 크기와 관련된 3 가지 조건 중 1 개만 표시하지만 ( "양수, 음수, 0, 텍스트" 로 코딩하지만 다음과 같이 표시하는 것을 선호 합니다. if isnumber 및 true, elseif isnumber 및 false, elseif number; elseif는 텍스트입니다 )

그래서 저에게 가장 좋은 대답은 David와 Grastveit의 다른 지역 형식에 대한 의견입니다.

내가 작성한 보고서에 따라 사용하는 것입니다.

[<1000000]#,##0.00," KB";[<1000000000]#,##0.00,," MB";#,##0.00,,," GB"

[>999999999999]#,##0.00,,,," TB";[>999999999]#,##0.00,,," GB";#.##0.00,," MB"

[<1000000]# ##0,00 " KB";[<1000000000]# ##0,00  " MB";# ##0,00   " GB"

[>999999999999]# ##0,00    " TB";[>999999999]# ##0,00   " GB";# ##0,00  " MB"

선택해라!

---

위의 서식 지정 방법은 작동하지만 세 가지 수준에서만 가능합니다. 위는 KB, MB 및 GB를 사용했습니다. 여기에서는 6 개로 확장했습니다. 셀을 마우스 오른쪽 버튼으로 클릭하고 셀 서식을 선택합니다. 숫자 탭에서 사용자 지정을 선택합니다. 그런 다음 유형 : 상자에 다음을 입력합니다.

[<1000]##0.00"  B";[<1000000]##0.00," KB";##0.00,," MB"

그런 다음 확인을 선택합니다. 여기에는 B, KB 및 MB가 포함됩니다. 그런 다음 동일한 셀을 선택한 상태에서 홈 리본, 조건부 서식, 새 규칙을 클릭합니다. 포함 된 셀만 서식을 선택합니다. 그런 다음 규칙 설명 아래에서 셀 값, 1000000000보다 크거나 같은 셀만 서식 지정 (즉, 9 개의 0) 그런 다음 서식, 숫자 탭, 사용자 지정을 클릭하고 유형 : 상자에 다음을 입력합니다.

[<1000000000000]##0.00,,," GB";[<1000000000000000]##0.00,,,," TB";#,##0.00,,,,," PB"

확인, 확인을 선택합니다. 이 조건부 서식은 값이 1,000,000,000보다 큰 경우에만 적용됩니다. 그리고 GB, TB 및 PB 범위를 처리합니다.

567.00  B
  5.67 KB
 56.70 KB
567.00 KB
  5.67 MB
 56.70 MB
567.00 MB
  5.67 GB
 56.70 GB
567.00 GB
  5.67 TB
 56.70 TB
567.00 TB
  5.67 PB
 56.70 PB

PB보다 큰 것은 56,700PB와 같이 더 큰 PB로 표시됩니다. 더 큰 값, EB 등을 처리하기 위해 다른 조건부 서식을 추가 할 수 있습니다.

---

내 지역 인 유럽에서 작동하도록 약간 변경했습니다 (. 천 단위 구분 기호, 쉼표 구분 기호) :

[<1000000]#.##0,00" KB";[<1000000000]#.##0,00.." MB";#.##0,00..." GB"

데이터 변환 (1000! = 1024)에 대한 여전히 동일한 문제이지만 나를 위해 일합니다.

---

바이너리 기가 바이트 (1024 * 1024 * 1024의 배수)를 표시하는 방법을 모르겠지만 다음과 같은 형식을 사용하여 10 진수 기가 바이트를 표시 할 수 있습니다.

0.00,,,"Gb"

---

위 수식은 첫 번째 줄에 빼기 기호가 필요합니다. "= IF (A1 <-999500000000"

=IF(A1<-999500000000,TEXT(A1,"#,##.#0,,,"" TB"""),
IF(A1<-9995000000,TEXT(A1,"#,##.#0,,,"" GB"""),
IF(A1<-9995000,TEXT(A1,"#,##0,,"" MB"""),
IF(A1<-9995,TEXT(A1,"#,##0,"" KB"""),
IF(A1<-1000,TEXT(A1,"#,##0"" B """),
IF(A1<0,TEXT(A1,"#,##0"" B """),
IF(A1<1000,TEXT(A1,"#,##0"" B """),
IF(A1<999500,TEXT(A1,"#,##0,"" KB"""),
IF(A1<999500000,TEXT(A1,"#,##0,,"" MB"""),
IF(A1<999500000000,TEXT(A1,"#,##.#0,,,"" GB"""),
TEXT(A1,"#,##.#0,,,,"" TB""")))))))))))

---

그리고 또 다른 해결책은 공학 표기법을 사용하는 것입니다. (지수가 항상 3의 배수라는 점을 제외하면 과학적 표기법과 같습니다.) 셀을 마우스 오른쪽 버튼으로 클릭하고 셀 서식을 선택합니다. 숫자 탭에서 사용자 지정을 선택합니다. 그런 다음 유형 : 상자에 다음을 입력합니다.

##0.00E+00

그런 다음 확인을 클릭하십시오. K, M 등 대신 +3, +6 등이 있습니다. 양수 및 음수뿐만 아니라 양수 및 음수에도 적용됩니다. -3은 m, -6은 u 등입니다.

567.00E-06
  5.67E-03
 56.70E-03
567.00E-03
  5.67E+00
 56.70E+00
567.00E+00
  5.67E+03
 56.70E+03
567.00E+03
  5.67E+06

---

Tera 미만은 GB에 기록하고 TB에 999GB 이상 기록합니다.

[<1000]0" GB";[>999]0.0," TB"

OR

[<1000]0" GB";[>=1000]0.0," TB"

---

I use CDH hadoop and when I export excel report, I have two problems;

1) convert Linux date to excel date,
For that, add an empty column next to date column lets say the top row is B4, paste below formula and drag the BLACK "+" all the way to your last day at the end of the column. Then hide the original column

=(((B4/1000/60)/60)/24)+DATE(1970|1|1)+(-5/24)

2) Convert disk size from byte to TB, GB, and MB
the best formula for that is this

[>999999999999]# ##0.000,,,," TB";[>999999999]# ##0.000,,," GB";# ##0.000,," MB"

it will give you values with 3 decimals just format cells --> Custom and paste the above code there

---

It is a bit of a "brute force" but works ;)

=IF(E4/1000<1;CONCATENATE(E4;" bps");IF(E4/1000<1000;CONCATENATE(ROUND(E4/1000;2);" kbps");IF(E4/1000000<1000;CONCATENATE(ROUND(E4/1000000;2);" mbps");IF(E4/1000000000<1000;CONCATENATE(ROUND(E4/1000000000;2);" gbps")))))

---

After seeing the answers here just improved on this formula to have decimal places on bigger values and cater for negative values.

=IF(A1<999500000000,TEXT(A1,"#,##.#0,,,"" TB"""),
IF(A1<-9995000000,TEXT(A1,"#,##.#0,,,"" GB"""),
IF(A1<-9995000,TEXT(A1,"#,##0,,"" MB"""),
IF(A1<-9995,TEXT(A1,"#,##0,"" KB"""),
IF(A1<-1000,TEXT(A1,"#,##0"" B """),
IF(A1<0,TEXT(A1,"#,##0"" B """),
IF(A1<1000,TEXT(A1,"#,##0"" B """),
IF(A1<999500,TEXT(A1,"#,##0,"" KB"""),
IF(A1<999500000,TEXT(A1,"#,##0,,"" MB"""),
IF(A1<999500000000,TEXT(A1,"#,##.#0,,,"" GB"""),
TEXT(A1,"#,##.#0,,,,"" TB""")))))))))))

---

I suspect a lot of the answers here are outdated, as I did not get the expected result from the given answer.

If you have value in KB that you would like to format according to the size, you can try the following.

---

Formula

[<1000]#" KB ";[<1000000]#0,00 " MB";0,## " GB"

---

Initial Value (in KB) => Output

952 => 952 KB

1514 => 1.51 MB

5122323 => 5.12 GB

참고URL : https://stackoverflow.com/questions/1533811/how-can-i-format-bytes-a-cell-in-excel-as-kb-mb-gb-etc